I have posted this elsewhere before. It works well:

#!/bin/tcsh
#
# To install, use either the MacOS X Terminal (Unix command line) app or the MacOS X GUI to save the
# contents of this file as a text-only file called makepile. Then, use: chmod +x makepile in Terminal
# to give makepile executable permission.

# Look below(after) the script for the usage example and text to create an input file for this script.

# script to read a filename list from standard input and make a piles (nested folders) of links to them
# ... for example, for inclusion in the dock

###
set folder = '.'
while ( 1 )
set filename = ($<)
@ nn = $#filename
if ( $nn > 1 && "$filename[1]" == "FOLDER" ) then
echo Now creating folder $filename[2]
if ( -e "$filename[2]" ) then
echo "******" Folder "$filename[2]" already exists ... existing folder is used.
else
mkdir "$filename[2]"
endif
set folder = "$filename[2]"
else
@ kk = $%filename
if ( "$filename" == "end-of-list" ) then
echo found\: $filename
break
else if ( $kk < 1 ) then # note "else if", not "elseif" !!!
echo "null line or end of file reached"
break
else
set f = "$filename"
echo f is $f
set froot = "${f:r}"
echo froot is $froot
set ftail = "${froot:t}"
echo ftail is $ftail
set flink = ${folder:q}/${ftail:q}
echo ---\> now creatink link as $flink:q for $filename in $folder
if ( -e "${filename:q}" ) then
ln -i -s "${filename:q}" "${flink:q}"
else
echo "******" File \"${filename:q}\" does not exist ... link not created.
endif
endif
endif
end
###

# Usage example:
#
# To see how to use makepile, do the following example.
#
# First, make a file called pileList and put the following lines that begin with #... into it.
# A file like this can be easily built by opening a blank file in MacOS X TextEdit and then dragging
# the desired file selections over the text page and letting up on the mouse button.
#
#... FOLDER ~/DockStuff
#... FOLDER ~/DockStuff/iLife
#... /Applications/iCal.app
#... /Applications/iDVD.app
#... /Applications/GarageBand.app
#... /Applications/iChat.app
#... /Applications/iWeb.app
#... /Applications/iTunes.app
#... /Applications/iPhoto.app
#... FOLDER ~/DockStuff/iWork
#... /Applications/iWork '08/Keynote.app
#... /Applications/iWork '08/Numbers.app
#... /Applications/iWork '08/Pages.app
#... FOLDER ~/DockStuff/iStudy
#... /Developer/Applications/Xcode.app
#... /Applications/Dictionary.app
#... /Applications/iCal.app
#... /Applications/Mail.app
#... /Applications/Safari.app
#... /Applications/Chess.app
#... /Applications/Calculator.app
#... /Applications/DVD Player.app
#... /Applications/Stickies.app
#... /Applications/TextEdit.app
#... /Applications/TextWrangler.app
#... /Applications/Delicious Library.app
#... /Applications/Graphing Calculator
#... /Users/KEP/Across Lite V2.1/Across Lite v2.0
#... /Applications/Dashboard.app
#... FOLDER ~/DockStuff/iArt
#... /Applications/iMovie (previous version).localized/iMovie HD.app
#... /Applications/DVD Player.app
#... /Applications/Front Row.app
#... /Applications/Photo Booth.app
#... /Applications/Preview.app
#... /Applications/QuickTime Player.app
#... /Applications/Soundtrack.app
#... /Applications/GraphicConverter/GraphicConverter.app
#... /Applications/Flip4Mac/WMV Player.app
#... FOLDER ~/DockStuff/Tech
#... /Applications/System Preferences.app
#... /Applications/Time Machine.app
#... end-of-list
#
# Next remove the #... at the beginnings of the lines (the beginning spaces too if you wish).
# Then save the file giving it the name pileList in the same folder as is this makepile file.
# NOTE! The file pileList must be saved as a text-only file.
#
# Using the Terminal (Unix command line) app, cd to the makepile folder and then
# enter the command string: ./makepile <pileList
#
# Then makepile runs and creates a folder in your home folder called DockStuff.
# Each sub-folder in DockStuff contains symbolic links (aliases) as specifed in pileList.
#
# For MacOS X Leopard the alias sub-folders can be dragged into the right side of the dock
# and will become piles from which the aliased apps and files can be accessed. Then the left
# side of the dock will show only apps that are running.
#
# There are hints elsewhere on the web (for example, www.leoparddocks.com) for customizing the
# dock appearance including fancy folder representations for each of the piles.
###